Press2Flash

public class Main extends Sprite 
{		
public function Main():void 
{
	if (stage) init();
	else addEventListener(Event.ADDED_TO_STAGE, init);
}
 
private function init(e:Event = null):void 
{
	removeEventListener(Event.ADDED_TO_STAGE, init);
 
	stage.scaleMode = StageScaleMode.NO_SCALE;
	stage.align 	= StageAlign.TOP_LEFT;
 
	/** Tell WPConfig where the plugin is located is located. */
	WPConfig.TEMPLATE_DIRECTORY	= Utils.extractPath(loaderInfo.loaderURL);
	/** and also where the template (theme) is. This will be usefull to load assets.
 	     Note that in this example, plugin_path is a HTML variable!*/
	WPConfig.PLUGIN_DIRECTORY	= loaderInfo.parameters.plugin_path;
 
	/** instanciate a new Wordpress connection.*/
	var wpConnect:WPConnection = new WPConnection();
	/** Add the events */
	wpConnect.addEventListener(WPConnectionEvent.COMPLETE, onConfigReceived);
	wpConnect.addEventListener(WPConnectionEvent.ERROR, onConfigError);
 
	/** The first thing you want to retrieve is your wordpress configuration. So let's get it! */
	var configSerialiser:GetConfigSerializer = new GetConfigSerializer();
	/** Give me the categories I created in Wordpress... */
	configSerialiser.output_categories = true;
	/** ...and the pages */
	configSerialiser.output_pages = true;
	/** send the request! */
	wpConnect.getConfig(configSerialiser);
}
 
private function onConfigError(evt:WPConnectionEvent):void
{
	trace("an error occured");
}
 
private function onConfigReceived(evt:WPConnectionEvent):void
{
	/** When the configuration has been received, save it using the WPConfig Class */
	var wp_config:WPConfig = new WPConfig(evt.data);
	/** load all your assets */
	loadAssets();
}
 
private function loadAssets():void
{
	/** in this simple exemple, we just need to load a stylesheet */
	var loader:URLLoader = new URLLoader(new URLRequest(WPConfig.TEMPLATE_URL+"flash.css"));
	loader.addEventListener(Event.COMPLETE, onAssetsLoaded);
}
 
private function onAssetsLoaded(evt:Event):void
{
	/** Parse the stylesheet to the StyleSheetManager.
	 * We are going to need it to display some text */
	StyleSheetManager.parseStyleSheet(evt.target.data);
 
	/** add a container in which all your content is going to be displayed */
	var container:Container = new Container();
	addChild(container);
 
}
}

public class Container extends Sprite
{
[Embed(source = '../lib/fonts.swf', fontFamily = 'Arial')]
private var Arial:Class;
 
public function Container() 
{
	if (stage) init();
	else addEventListener(Event.ADDED_TO_STAGE, init);
}
 
private function init(e:Event = null):void 
{
	removeEventListener(Event.ADDED_TO_STAGE, init);
 
	/** instanciate a new Wordpress connection.*/
	var wp_connection:WPConnection = new WPConnection();
	/** add the events */
	wp_connection.addEventListener(WPConnectionEvent.COMPLETE, onPostReceived);
	wp_connection.addEventListener(WPConnectionEvent.ERROR, onPostError);
 
	/** This will provide some variables that you can fill to build the request */
	var post_serializer:GetPostSerializer = new GetPostSerializer();
	/** this means: give me the wordpress post that has the ID 1 */
	post_serializer.post_id = 1;
	/** show the associated custom fields */
	post_serializer.output_customfields = true;
	/** the post has to be a post (meaning not a page, attachment or revision) */
	post_serializer.post_type = "post";
 
	/** proceed to the request */
	wp_connection.getPost(post_serializer);
}
 
private function onPostReceived(evt:WPConnectionEvent):void
{
	/** When the XML sent from the backend has been received, you can retrieve the content this way: */
	var wp_content:XML = evt.data;
 
	/** Use the StyledTextField Class to easily create a textfield with CSS support */
	var post_title:StyledTextField = new StyledTextField("<h1>" + wp_content.post_title + "</h1>", { embedFonts:false } );
	post_title.x = 20;
	post_title.y = 20;
	addChild(post_title);
 
	var post_content:StyledTextField = new StyledTextField("<p>" + wp_content.post_content + "</p>", { embedFonts:false } );
	post_content.x = 20;
	post_content.y = post_title.y + post_title.height + 10;
	addChild(post_content);
 
	/** Set the browser title using SWFAddress */
	SWFAddress.setTitle(WPConfig.blogName + " - " + wp_content.post_title);
}
 
private function onPostError(evt:WPConnectionEvent):void
{
	trace("the post has not been found");
}
}